Datei:Bierverbrauch-DEU-jeKopf.svg
Originaldatei (SVG-Datei, Basisgröße: 500 × 400 Pixel, Dateigröße: 32 KB)
Diese Datei und die Informationen unter dem roten Trennstrich werden aus dem zentralen Medienarchiv Wikimedia Commons eingebunden.
Beschreibung
BeschreibungBierverbrauch-DEU-jeKopf.svg |
Deutsch: Bierverbrauch in Deutschland je Kopf der Bevölkerung in Litern |
Datum | |
Quelle | Eigenes Werk |
Urheber | Makrameus |
SVG‑Erstellung InfoField | |
Quelltext InfoField |
# gnuplot
### Variablen - die wichtigsten Paramter dieser Grafik:
# (in der Regel wird es reichen für eine neue Grafik diese Werte zu ändern)
my_data = 'Bierverbrauch-DEU-jeKopf.dat'
my_xrange_min = '1940'
my_xrange_max = '2025'
my_xtics_years = '10'
my_mxtics = '2'
my_yrange_min = '0' # bei '-1' wird der erste
# Achsenstrich unter Null berechnet
my_yrange_max = '180' # hier ist '*' erlaubt und sinnvoll
my_ytics = '20'
my_ymtics = '1'
### Farben - nummerische Equavalente zu Namen nach:
# https://stackoverflow.com/questions/54658674/gnuplot-apply-colornames-from-datafile
# Die beiden Ziffen am Ende der Variablen geben opacity/transparenz an
#
my_darkred_00 = '#008B0000'; my_darkred_20 = '#208B0000';
my_darkred_40 = '#408B0000'; my_darkred_60 = '#608B0000';
my_darkred_80 = '#808B0000'; my_darkred_a0 = '#a08B0000';
my_darkred_c0 = '#c08B0000'; my_darkred_e0 = '#e08B0000';
#
my_darkblue_00 = '#0000008B'; my_darkblue_20 = '#2000008B';
my_darkblue_40 = '#4000008B'; my_darkblue_60 = '#6000008B';
my_darkblue_80 = '#8000008B'; my_darkblue_a0 = '#a000008B';
my_darkblue_c0 = '#c000008B'; my_darkblue_e0 = '#e000008B';
#
my_darkorange_00 = '#00FF8C00'; my_darkorange_20 = '#20FF8C00';
my_darkorange_40 = '#40FF8C00'; my_darkorange_60 = '#60FF8C00';
my_darkorange_80 = '#80FF8C00'; my_darkorange_a0 = '#a0FF8C00';
my_darkorange_c0 = '#c0FF8C00'; my_darkorange_e0 = '#e0FF8C00';
#
my_black_00 = '#00000000'; my_black_20 = '#20000000';
my_black_40 = '#40000000'; my_black_60 = '#60000000';
my_black_80 = '#80000000'; my_black_a0 = '#a0000000';
my_black_c0 = '#c0000000'; my_black_e0 = '#e0000000';
#
my_lemonchiffon = '#ffffc0'
### Allgemeines zu den Eingabedaten
set timefmt "%Y" # Zeitangaben in YYYY
set datafile separator ";" # Spaltenseparator
set datafile commentschars "#" # Kommentarzeichen
stats my_data u (strptime("%Y",strcol(1))) nooutput
my_diff = (STATS_max - STATS_min) / (60*60*24*365.25)
print ' -----Stats-(Timestamp)----------------------'
print ' Erster Wert der Datendatei: ', strftime("%Y", STATS_min)
print ' Letzter Wert der Datendatei: ', strftime("%Y", STATS_max)
print ' Diff in Jahren: ', sprintf("%.2f", my_diff)
print ' --------------------------------------------'
# Anmerk.: die ausgegebenen Timestamps können in einer Shell bequem mit
# 'date -d @[Wert]' in humanleserliches Format gewandelt werden
### Allgemeines zur Ausgabe
unset key # alle Werte für Legende aufheben (werden gleich gesetzt)
set key vertical maxrows 2 # max Anzahl Zeilen der Legende
set key at graph 0.25,0.10 # Legende weit links-unten (Pos. bezogen auf Graph)
set key left bottom # Punkt der Legendenbox an dem sie ausgerichtet wird
set key nobox # Legende o. Rahmen (zu Testzwecken box setzen!)
set key noopaque # Transparenz
set key width -10 # Breite schmaler
set key samplen 2 # Breite der Linenbeispiele
# das 'unset key' einfach auskommentieren um eine
# vernünftige Legende auszugeben
set style data lines # wird bei 'plot' überschrieben
#set style fill transparent solid 0.4 # wird ebenfalls bei 'plot' überschrieben
set border 3 # Rahmen unten (Bit 1) und links (+ Bit 2)
set grid # Gitterlinien verwenden
# Gitterlinien per Hand setzen falls gewünscht
# set style line 1 linetype rgb '#4F4F4F' linewidth 0.5 dashtype 2 # Def. Major-grid
set style line 1 linecolor rgb my_darkred_80 linewidth 2.0 # Def. Major-grid
set style line 2 linecolor rgb my_darkblue_40 linewidth 1.0 # def. Minor-grid
set grid xtics mxtics # eventuell noxtics und nomxtics
set grid ytics mytics # eventuell noytics und nomytics
set grid back # Gitter im Hintergrund
set grid linestyle 1, linestyle 2 # Setzen des linestyle für Major u. Minor
# show grid # Kontrollausgabe auf der Konsole
### Bereiche/Format/etc X-Achse
set xdata time # X-Achse als Zeitachse
set xlabel 'Jahr' # Beschriftung X-Achse
set xlabel offset 0, 0.75 # Schrift etwas höher
set xrange [ my_xrange_min : my_xrange_max]
# Wertebreich der X-Achse
set xtics '1000', (60*60*24*365.25) * my_xtics_years
# xtics in Sekunden
# der Beginn (Wert vor dem Komma) der X-Einteilung
# kann außerhalb xrange liegen
set xtics offset 0, 0.5 # Beschriftung näher an die X-Achse
set mxtics my_mxtics # Skalenstriche
set xtics nomirror # Nur unten Skalieren
set format x '%3Y' # Beschr.format JJJJ (bei 3 Stellen o. führend 0)
set xtics out # Skal. aussen damit sie nicht von Grafik
# überschr. wird
### Bereiche/Format/etc Y-Achse
set ylabel 'Liter je Einwohner' offset 2 # Abstand Achse/Label
# Untere Begrenzung des Bereichs der Y-Achse
# Falls my_yrange_min wird der erste Achsenstrich unterhalb der
# Nulllinie berechnen falls my_yrange gleich -1
if (my_yrange_min eq '-1' ) {
my_yrange_min = - my_ytics / my_ymtics
# für den Fall Nullline etwas fetter
set arrow from my_xrange_min, '0' to my_xrange_max, '0' nohead lc rgb '#C0000000' back
}
set yrange [ my_yrange_min : ]
# Obere Begrenzung des Bereichs der Y-Achse
# wir Testen ob der Wert der Var. my_yrange_max ein '*' ist und reagieren
# entsprechend weil der '*' sich nicht direkt via Var. setzen lässt.
if ( ( my_yrange_max eq '*' )) set yrange [ : * ]
if (!( my_yrange_max eq '*' )) set yrange [ : my_yrange_max ]
set ytics my_ytics # Anzahl der kleinen Teilstriche
set ytics offset 0.9 # Schrift etwas nach rechts
set ytics nomirror # oben keine Teilstriche
# Abfrage nach Betriebssystem und Aufruf spezifischer Befehle für
# Dezimal- und Tausenderseparator für die y-Achse
# Bei dem Betriebssystemaufruf verwenden wir den Befehl 'echo' weil den
# jedes Betriebssysem kennt und so keinen gnuplot-Fehler erzeugt
if ("Linux" eq "`echo $(uname -s)`") {
# Einstellungen für Linux
print "Wir setzten Dezimal- und Tausenderseparator nach Linux Art"
set decimalsign locale "de_DE.utf8"
set format y "%'.0f"
} else {
# Einstellungen für Windows
print "Wir setzten Dezimal- und Tausenderseparator nach Windows Art"
set decimalsign locale;
set decimalsign ",";
set format y "%'g"
}
set mytics my_ymtics # Unterskalierung
set ytics out # Skal. aussen da sie sonst von Grafik
# überschr. wird
### Außenränder (keine Angabe entspricht Automatik)
# keine Angabe hinter Xmargin entspr auto
# zur Positionierung siehe 'Coordinates' in:
# http://gnuplot.sourceforge.net/docs_4.2/node49.html#448
set lmargin
set rmargin at screen 0.990
set bmargin at screen 0.175
set tmargin at screen 0.960
# grauer Hintergrund für Testzwecke
# set object rectangle from screen 0,0 to screen 1,1 fillcolor rgb my_black_e0 behind
set object rectangle from graph 0, graph 0 to graph 1, graph 1 behind fillcolor rgb my_lemonchiffon # Zeichenbereich einfärben
### Dateiausgabe definieren
# Ausgabeformat: Wir erzeugen SVG
set output 'Bierverbrauch-DEU-jeKopf.svg'
set encoding utf8 # falls bei Windows iso_8859_1 stellen wir es um
# set term svg size 800,400 font "Arial,16" background rgb "gray75" # Hintergrund grau eingefärbt
set term svg size 500,400 font "Arial,16" background rgb "cyan"
# Die Parameter von 'set term' sind so gewählt, das man in Wikipedia bei einer
# Einbindung [[Datei:Einwohnerentwicklung_von_Moers.svg|mini|400px|Text]] noch Schrift/Details
# erkennen kann.
### Log10 Skalierung für Y-Achse wählen
# Für Formatparam siehe http://gnuplot.sourceforge.net/docs_4.2/node184.html
# Wert für ytics hier mit 10 Überschreiben damit die Mantisse wegfallen kann.
# Ansonsten müsste sie wie in 'set format y "%.1l*10^{%L}"; set ytics 5' angegeben
# werden was ungerade Werte ergibt.
# xrange muss größer Null beginnen. Kann oben mit my_yrange_min auf 10, 100, 1000 ...
# gesetzt werden oder hier auskommentieren.
# set logscale y 10; set format y " 10^{%L}"; set ytics 10; set mytics 10;
# set lmargin 5 # ev. bei 'Schwestergrafik' gleichen fixen Wert setzen.
# set yrange [ 100 : 1000000 ] # yrange manuell Anpassen!!!
### Abkürzungen hinter dem Plot-Befehl:
# u : using
# w : with
# lc : linecolor
# lt : linetype
# lw : linewidth
# pt : pointtype
# ps : pointsize
# lp : linespoints
# p : points
# t : title
# not : notitle
# filledc : filledcurves (Bsp.: File:Einwohnerentwicklung von Wanne-Eickel.svg)
# rgb : RedGreenBlue
# ax ; axes (bei der Plotanweisung meist x1y1)
# dt ; dashtype (Wert 1 entspricht normale durchgezogene Linie)
### Daten per Here-Document
# (siehe Abschntt 'Inline data and datablocks' in
# http://www.gnuplot.info/docs_5.2/Gnuplot_5.2.pdf )
#
$my_HD_1 << EndOfData_1
# bei 'plot' mit '$my_HD_1 use 1:2 with ...' einbinden
...
EndOfData_1
### Plot
# Jede Kurve wird zweimal gezeichnet. Beim ersten mal mit etwas Transparenz
# damit es heller wird. Beim zweiten mal werden die Punkt dunkel
# nachgezeichnet. Dadurch sollte der Betrachter besser erkennen können, wo
# Messpunkte fehlen.
#
# Erzeugen der Ausgabe
plot \
my_data u 1:2 ax x1y1 w lp lc rgb my_darkorange_40 lt 1 lw 5.5 pt 7 ps 0.22 t 'Bierverbrauch in Deutschland',\
# my_data u 1:2 ax x1y1 w p lc rgb my_darkorange_00 lt 1 lw 1.5 pt 7 ps 0.22 not ,\
# $my_HD_1 u 1:2 ax x1y1 w lp lc rgb my_darkred_40 lt 1 lw 1.5 pt 7 ps 0.22 t 'Einw. Entw.',\
# $my_HD_1 u 1:2 ax x1y1 w p lc rgb my_darkred_00 lt 1 lw 1.5 pt 7 ps 0.22 not ,\
Die folgenden Daten bitte in eine Textdatei unter dem Namen "Bierverbrauch-DEU-jeKopf.dat" abspeichern und ins gleiche Verzeichnis wie das GnuPlot-Script ablegen. <br>
Sollte jemand bessere / vollständigere Daten besitzen ist eine Änderung der nachstehenden Datendatei bzw. eine Neuerstellung der Grafik ausdrücklich erwünscht.
# Quellen
# https://de.statista.com/statistik/daten/studie/4628/umfrage/entwicklung-des-bierverbrauchs-pro-kopf-in-deutschland-seit-2000/
# https://web.archive.org/web/20140222204507/https://www.destatis.de/DE/Publikationen/Thematisch/FinanzenSteuern/Steuern/Verbrauchsteuer/Verbrauchsteuerstatistik5791001097004.html8
# https://www.statistischebibliothek.de/mir/receive/DESerie_mods_00000147
1950; 35,6
1955; 61
1960; 94,7
1965; 120
1970; 141,1
1975; 150
1976; 151
1980; 145,9
1985; 142
1990; 141
1991; 141,2
1992; 143,3
1993; 130,3
1994; 132,7
1995; 131,1
1996; 127,3
1997; 126,7
1998; 123,0
1999; 123,1
2000; 121,0
2001; 118,3
2002; 117,8
2003; 114,0
2004; 112,0
2005; 111,0
2006; 111,8
2007; 107,9
2008; 107,1
2009; 105,1
2010; 102,3
2011; 103,5
2012; 101,0
2013; 99,1
2014; 99,1
2015; 97,6
2016; 96,2
2017; 93,7
2018; 94,2
2019; 92,1
2020; 87,1
# EOF
|
Erzeugt mit gnuplot nach der Vorlage Altersstruktur von Köln - Teilbereich.svg
Mein Dank gilt Summer ... hier! der die Grundlagen für die gpl-Datei mit seinen Grafiken zur Einwohnerentwicklung (beispielsweise Einwohnerentwicklung von Moers.svg) gelegt hat.
Sollte jemand bessere / vollständigere Daten besitzen ist eine Änderung der Datendatei (weiter unten) und eine Neuerstellung der Grafik ausdrücklich erwünscht.
Lizenz
Diese Datei wird unter der Creative-Commons-Lizenz „CC0 1.0 Verzicht auf das Copyright“ zur Verfügung gestellt. | |
Die Person, die das Werk mit diesem Dokument verbunden hat, übergibt dieses weltweit der Gemeinfreiheit, indem sie alle Urheberrechte und damit verbundenen weiteren Rechte – im Rahmen der jeweils geltenden gesetzlichen Bestimmungen – aufgibt. Das Werk kann – selbst für kommerzielle Zwecke – kopiert, modifiziert und weiterverteilt werden, ohne hierfür um Erlaubnis bitten zu müssen.
http://creativecommons.org/publicdomain/zero/1.0/deed.enCC0Creative Commons Zero, Public Domain Dedicationfalsefalse |
In dieser Datei abgebildete Objekte
Motiv
Einige Werte ohne einen Wikidata-Eintrag
14. Juli 2020
image/svg+xml
e645b1f51d43b95927b9aa094ed5d0d1ca2487b2
32.979 Byte
400 Pixel
500 Pixel
Dateiversionen
Klicke auf einen Zeitpunkt, um diese Version zu laden.
Version vom | Vorschaubild | Maße | Benutzer | Kommentar | |
---|---|---|---|---|---|
aktuell | 21:29, 30. Jun. 2021 | 500 × 400 (32 KB) | Makrameus | Aktualisierung mit Werten für 2019 und 2020 | |
18:13, 14. Jul. 2020 | 500 × 400 (32 KB) | Makrameus | Uploaded own work with UploadWizard |
Dateiverwendung
Die folgenden 2 Seiten verwenden diese Datei:
Metadaten
Diese Datei enthält weitere Informationen (beispielsweise Exif-Metadaten), die in der Regel von der Digitalkamera oder dem verwendeten Scanner stammen. Durch nachträgliche Bearbeitung der Originaldatei können einige Details verändert worden sein.
Kurztitel | Gnuplot |
---|---|
Bildtitel | Produced by GNUPLOT 5.2 patchlevel 8 |
Breite | 500 |
Höhe | 400 |